{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
    flake-parts.url = "github:hercules-ci/flake-parts";
    systems.url = "github:nix-systems/default";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = import inputs.systems;

      perSystem = { pkgs, lib, ... }:
        let
          java = pkgs.jdk8;

          nativeBuildInputs = with pkgs; [
            java
            git
          ];

          buildInputs = with pkgs; [
            # OpenGL
            libGL
            mesa

            # X11 — required by LWJGL 2.9.4
            xorg.libX11
            xorg.libXcursor
            xorg.libXext
            xorg.libXi
            xorg.libXinerama
            xorg.libXrandr
            xorg.libXxf86vm
            xorg.libXrender
            xorg.libXfixes

            # Audio
            libpulseaudio
            flite
          ];
        in {
          devShells.default = pkgs.mkShell {
            inherit nativeBuildInputs buildInputs;

            env = {
              JAVA_HOME = "${java.home}";
              LD_LIBRARY_PATH = lib.makeLibraryPath buildInputs;
            };
          };
        };
    };
}